2-2

adj[x_]:=Conjugate[Transpose[x]]
InnerProd[x_,y_]:=(adj[x].y)[[1]][[1]]
p_⊗q_:=KroneckerProduct[p,q]

Purification of Quantum Mixtures

Nicholas Wheeler
11 February 2013

NOTE: This is an updated revision of a notebook written (in Mathematica v5) in October 2006.

"Purification" is a concept developed and employed in all quantum information texts (see, for example, Michael Nielsen & Isaac Chang, Quantum Computation & Quantum Information (2000), page 110; Teiko Heinosaari & Mario Ziman, The Mathematical Language of Quantum Theory: From Uncertainty to Entanglement (2012), §2.4.2; Maximilian Schlosshauer, Decoherence & the Quantum-to-Classical Transition (2008), §2.15.3; Stephen Barnett, Quantum Information (2009), Appendix Q). Useful because of exceptionally clear brevity is the account provided in

Hyperlink["Purification","ttp://en.wikipedia.org/wiki/Purification_of_quantum_state"]

The basic idea

Let the n×n density matrix ρ describe a mixture of quantum states that live in (Subscript[ℋ, n]). I construct, by two different methods, examples of such a density matrix, on the presumption that n = 3:


FIRST METHOD (see "Schmidt Decomposition"):

Table[(Subscript[x, k])=RandomComplex[{-1-I,1+I},{3,1}],{k,1,5}];
Table[(Subscript[ξ, k])=(Subscript[x, k])/Norm[(Subscript[x, k])],{k,1,5}];
ProbListX=Table[(Subscript[xp, k])=RandomReal[{}],{k,1,5}];
Table[(Subscript[px, k])=(Subscript[xp, k])/Total[ProbListX],{k,1,5}];
(Subscript[ρ, 1])=Chop[Sum[(Subscript[px, k])(Subscript[ξ, k]).adj[(Subscript[ξ, k])],{k,1,5}]];
(Subscript[ρ, 1])//MatrixForm
Eigenvalues[(Subscript[ρ, 1])]//Chop
Tr[(Subscript[ρ, 1])]
Tr[(Subscript[ρ, 1]).(Subscript[ρ, 1])]//Chop

SECOND METHOD (Wishart):

𝕎=RandomComplex[{-1-I,1+I},{3,3}];
𝕨=adj[𝕎].𝕎;
(Subscript[ρ, 2])=Chop[(𝕨/(Tr[𝕨]))];
(Subscript[ρ, 2])//MatrixForm
Eigenvalues[(Subscript[ρ, 2])]//Chop
Tr[(Subscript[ρ, 2])]
Tr[(Subscript[ρ, 2]).(Subscript[ρ, 2])]//Chop

The claim is that it is always possible (in multiple ways) to recover any such density matrix as a partial trace of the density matrix associated with a pure state ψ that lives in (Subscript[𝒢,  3n]) = (Subscript[ℋ,  3])⊗(Subscript[𝒥, n ])with n ⩾ 3. Here (Subscript[𝒥, n]) is a "spectator," introduced to make purification possible, but usually of no independent physical interest.

Demonstration

Construct the material that feeds into the spectral representation of (Subscript[ρ, 1]):

Table[(Subscript[λ, j])=Chop[Eigenvalues[(Subscript[ρ, 1])]][[j]],{j,1,3}];
Table[(Subscript[u, j])=Transpose[{Chop[Eigenvectors[(Subscript[ρ, 1])][[j]]]}],{j,1,3}];
Table[Chop[InnerProd[(Subscript[u, j]),(Subscript[u, k])]],{j,1,3},{k,1,3}]//MatrixForm
Chop[(Subscript[ρ, 1])-(∑_(j=1)^3)(Subscript[λ, j])(Subscript[u, j]).adj[(Subscript[u, j])]]//MatrixForm

We need now a set (any set) of 3 orthonormal vectors drawn from (Subscript[𝒥, 4]). It is simplest to take those to be 3 of the eigenvectors of an arbitrarily constructed 4×4 Wishart matrix (all such matrices are hermitian, and their eigenvectors therefore orthogonal…and already normalized as Mathematica supplies them):

ℤ=RandomComplex[{-1-I,1+I},{4,4}];
𝕫=adj[ℤ].ℤ;
Table[(Subscript[v, k])=Transpose[{Chop[Eigenvectors[𝕫][[k]]]}],{k,1,3}];
Table[Chop[InnerProd[(Subscript[v, j]),(Subscript[v, k])]],{j,1,3},{k,1,3}]//MatrixForm

Constuct now (in Schmidt decomposed form) the 12-vector

ψ=(∑_(j=1)^3)(Sqrt[(Subscript[λ, j])])(Subscript[u, j])⊗(Subscript[v, j]);

and the associated pure density matrix

ℝ=Chop[ψ.adj[ψ]];

Dimensions[ℝ]

Tr[ℝ]
Tr[ℝ.ℝ]//Chop

Construct partial trace operations appropriate to the 3:4 partitioning of 12-space

(Subscript[𝕀, 3])=IdentityMatrix[3];
(Subscript[𝕀, 4])=IdentityMatrix[4];

Table[(Subscript[e, j])=Transpose[{(Subscript[𝕀, 3])[[j]]}],{j,1,3}];
Table[(Subscript[f, k])=Transpose[{(Subscript[𝕀, 4])[[k]]}],{k,1,4}];

(Subscript[Tr, A])[x_]:=(∑_(j=1)^3)(Transpose[(Subscript[e, j])]⊗(Subscript[𝕀, 4])).x.((Subscript[e, j])⊗(Subscript[𝕀, 4]))
(Subscript[Tr, B])[x_]:=(∑_(k=1)^4)((Subscript[𝕀, 3])⊗Transpose[(Subscript[f, k])]).x.((Subscript[𝕀, 3])⊗(Subscript[f, k]))

and recover (Subscript[ρ, 1])  as the density matrix that results when the 𝒥-component of ℝ is traced out:

Chop[(Subscript[Tr, B])[ℝ]-(Subscript[ρ, 1])]//MatrixForm

Which establishes that ℝ is one of the infinitely many possible "purifications" of (Subscript[ρ, 1]).

Comments

The spectral decomposition of (Subscript[ρ, 1 ])

can be written

where the ℙ-matrices comprise a complete set of orthogonal hermitian projection matrices. Writing

(which is hermitian because the λs are non-negative real numbers) we have

which is the "Wishart representation" of (Subscript[ρ, 1]).

I constructed (Subscript[ρ, 1])and (Subscript[ρ, 2]) by alternative methods because I was aware (see "Some Miscellaneous Adventures in Experimental Mathematical Physics," notes for a Reed College Physics Seminar presented 9 November 2011) that the spectra of large hermitian matrices of the form

conform to the Wigner semicircle distribution, while the spectra of large hermitian matrices of Wishart design

conform to the Marchenko-Pastur distribution. But it is clear that (Subscript[ρ, 2]) can be purified by precisely the means that served to purify (Subscript[ρ, 1]), so I omit the explicit demonstration.

One encounters purification most often in the context of arguments that begin with words to the effect that "We can (by purification) assume without loss of generality that ρ is pure, so…"

The idea of achieving simplification by expanding the dimension is encountered in many contexts: think of the embedding problem in differential geometry. Or of the Neumark dilation theorem, which asserts that POVMs in n-space can be realized as projection-valued measures in a space of higher dimension N. See pages 16-18 in "Generalized Quantum Measurements" (2012) and

Hyperlink["POVMs, Neumark's Theorem & Quantum Measurement","http://en.wikipedia.org/wiki/POVM"]

or §3.1.4 in

Hyperlink["Preskill's Quantum Information Notes","http://www.theory.caltech.edu/people/preskill/ph229/notes/book.ps"]

Related mathematical material can be found in

Hyperlink["Choi's Theorem","http://en.wikipedia.org/wiki/Choi%27s_theorem_on_completely_positive_maps"]

On pages 12 & 13 of "Selected topics in Quantum Measurement Theory" (2009) I am led to contemplate notions that I call "disentanglement by measurement" and "purification by measurement."